2次元のベクトルの回転は、入試問題の範囲のせいか解説するサイトは多い気がします。
塾講師によるyoutube解説もあったりするのでゲーム開発する側にとっては助かりますね。
さて、レーダーみたいなのという事なので作ってみました。
「レーダーのようなもの」という感じで出力したいことの具体的なイメージを提示してもらえるとやりたいことが伝わるのでありがたいです。
#module
; ベクトル回転
; ↓2次元の回転行列と書かれている部分の式を使います。
; https://w3e.kanazawa-it.ac.jp/math/category/gyouretu/senkeidaisu/henkan-tex.cgi?target=/math/category/gyouretu/senkeidaisu/rotation_matrix.html&pcview=2
#deffunc kaiten var vx, var vy, double x, double y, double r
vx = x*cos(r) - y*sin(r)
vy = x*sin(r) + y*cos(r)
return
; 回転中心
#deffunc setcenter double p_cx, double p_cy
cx = p_cx
cy = p_cy
return
; 設定し座座標を中心に回転
; ↓図だけ見てイメージをつかんでください。
; https://imagingsolution.net/math/rotate-around-point/
#deffunc kaiten_center var v_vx, var v_vy, double p_x, double p_y, double p_r
; 回転中心座標を原点へ移動
x = p_x - cx
y = p_y - cy
; 原点周りにp_rラジアン回転
v_vx = x*cos(p_r) - y*sin(p_r)
v_vy = x*sin(p_r) + y*cos(p_r)
; 回転中心を元に戻す
v_vx += cx
v_vy += cy
return
#global
screen 0, 640,480
;自機
jx = 640.0/2
jy = 480.0/2
jr = 0.0
;敵
tx = jx
ty = jy - 10.0
; ウィンドウの中央
cwx = ginfo_winx / 2
cwy = ginfo_winy / 2
*main
redraw 1
await 16
gsel 0
redraw 0
color 0,0,0
boxf
stick key, 31
//移動
; 自機
if key&1 : jr -= deg2rad(1) ;←
if key&4 : jr += deg2rad(1) ;→
if key&2 { ;↑
kaiten x,y, 0, -2, jr ; 自機の向きに合わせて進む向きを回転する
jx += x
jy += y
}
; 敵
ty = ty - 1.0
// ビュー変換
; 自機の座標をカメラの中央にする。
; 回転の中心座標
setcenter jx, jy
kaiten_center vjx, vjy, jx, jy, -jr
kaiten_center vtx, vty, tx, ty, -jr
; 自機を画面の中央にする
vtx = vtx - vjx + cwx
vty = vty - vjy + cwy
vjx = vjx - vjx + cwx
vjy = vjy - vjy + cwy
//自機
color,255,0
pos vjx, vjy
mes"▲"
//敵
color 255,0,0
pos vtx, vty
mes"◇"
//
goto *main
ちゃんと動いてるかな…背景がないからよくわからない。(´・ω・｀)
基本的な考え方は、自機や敵が動く空間があり、それをカメラで追いかけているイメージです。
ウィンドウ上に表示すのは、カメラに映った映像です。
自機や敵が動く空間の座標系とカメラの座標系の2つがあるので分けて考えないと作りやすいです。
まず自機や敵が動く空間で自機や敵を動かします。
次に自機や敵の座標をカメラから見た座標に変換します。ビュー変換と書いてるところですね。
あとはカメラから見た座標に変換した結果を描画すれば完成です。
ベクトルの回転部分はよく使うので関数にしました。
中に書いている式はベクトルを回転する物ですが…とりあえずこういうものだと思ってまずは使ってみてよいと思います。
興味があれば2次元ベクトルの回転について調べてみるとよいと思います。理解して使えるようになるととても便利ですよ。
またその一方で、難しい数学計算はモジュールに任せるというのも良い手だと思います。
d2cモジュール
https://mclab.uunyan.com/dl/dl50.htm
追伸：記事の削除はトラブルでもない限り削除しないでほしいです。
後で同じ悩みを抱える方が見た際に内容が追えなくなってしまうので。
(投稿者削除)
