rem gccでコンパイル＆実行
rem gcc32_and_run.bat
@rem 内容が古くなっているかもしれないので
@rem その場合は修正して使用して下さい
@echo off
rem コンソールアプリケーション専用
title Ｃソースのコンパイルと実行

if /i %~x1 == .c   (goto compile)
if /i %~x1 == .cpp (goto compile)
if /i %~x1 == .h   (goto compile)
echo エラー
echo Ｃ言語のソースファイルではありません。
goto end


:compile
echo Ｃのソースファイルをコンパイルします。
echo.

echo ^>カレントディレクトリ
echo %~dp1
echo.

%~d1
cd "%~dp1"

echo ^>コマンド
echo gcc "%~nx1"
echo.

setlocal
rem 次の行をお使いのPCのMinGWのPATHに書き換えてください
path C:\MinGW64\bin
gcc.exe -Wall "%~nx1"
endlocal

if exist "a.exe" (
	goto exe
) else (
	goto end
)


:exe
echo.
echo ^>実行
echo "a.exe"
echo.

echo #### 開始 ####
"a.exe"
echo.
echo #### 終了 ####

del "a.exe"


:end
echo.
echo.
pause
@rem このスクリプトは著作権者のtytyさんの意向で
@rem NYSLとしています
@rem NYSL Version 0.9982